root/Trunk/WebGUI/dev/Asset.pm

package WebGUI::Asset;

=head1 LEGAL

 -------------------------------------------------------------------
  WebGUI is Copyright 2001-2006 Plain Black Corporation.
 -------------------------------------------------------------------
  Please read the legal notices (docs/legal.txt) and the license
  (docs/license.txt) that came with this distribution before using
  this software.
 -------------------------------------------------------------------
  http://www.plainblack.com                     info@plainblack.com
 -------------------------------------------------------------------

=cut

use WebGUI::AssetBranch;
use WebGUI::AssetClipboard;
use WebGUI::AssetExportHtml;
use WebGUI::AssetLineage;
use WebGUI::AssetMetaData;
use WebGUI::AssetPackage;
use WebGUI::AssetTrash;
use WebGUI::AssetVersioning;
use strict;
use Tie::IxHash;
use WebGUI::AdminConsole;
use WebGUI::Cache;
use WebGUI::Form;
use WebGUI::HTML;
use WebGUI::HTMLForm;
use WebGUI::TabForm;
use WebGUI::Utility;

=head1 NAME

Package WebGUI::Asset

=head1 DESCRIPTION

Package to manipulate items in WebGUI's asset system. Replaces Collateral.

=head1 SYNOPSIS

An asset is the basic class of content in WebGUI. This handles security, urls, and other basic information common to all content items.

A lineage is a concatenated series of sequence numbers, each six digits long, that explain an asset's position in its familiy tree. Lineage describes who the asset's ancestors are, how many ancestors the asset has in its family tree (lineage length), and the asset's position (rank) amongst its siblings. In addition, lineage provides enough information about an asset to generate a list of its siblings and descendants.

 use WebGUI::Asset;

=head1 METHODS

These methods are available from this class:

=cut


#-------------------------------------------------------------------

=head2 addMissing ( url )

Displays a message to the admin that they have requested a non-existent page and give them an option to create it.

=head3 url

The missing URL.

=cut

sub addMissing {
        my $self = shift;
        my $assetUrl = shift;
        return undef unless ($self->session->var->isAdminOn);
        my $ac = $self->getAdminConsole;
        my $i18n = WebGUI::International->new($self->session, "Asset");
        my $output = $i18n->get("missing page query");
        $output .= '<ul>
                        <li><a href="'.$self->getUrl("func=add;class=WebGUI::Asset::Wobject::Layout;url=".$assetUrl).'">'.$i18n->get("add the missing page").'</a></li>
                        <li><a href="'.$self->getUrl.'">'.$i18n->get("493","WebGUI").'</a></li>
                        </ul>';
        return $ac->render($output);
}

#-------------------------------------------------------------------

=head2 canAdd ( session, [userId, groupId] )

Verifies that the user has the privileges necessary to add this type of asset. Return a boolean.

=head3 session

The session variable.

=head3 userId

Unique hash identifier for a user. If not supplied, current user.

=head3 groupId

Only developers extending this method should use this parameter. By default WebGUI will check groups in this order, whichever is defined: Group id assigned in the config file for each asset. Group assigned by the developer in the asset itself if s/he extended this method to do so. The "turn admin on" group which is group id 12.

=cut

sub canAdd {
        my $className = shift;
        my $session = shift;
        my $userId = shift || $session->user->userId;
        my $user = WebGUI::User->new($session, $userId);
        my $subclassGroupId = shift;
        my $addPrivs = $session->config->get("assetAddPrivilege");
        my $groupId = $addPrivs->{$className} || $subclassGroupId || '12';
        return $user->isInGroup($groupId);
}


#-------------------------------------------------------------------

=head2 canEdit ( [userId] )

Verifies group and user permissions to be able to edit asset. Returns 1 if owner is userId, otherwise returns the result checking if the user is a member of the group that can edit.

=head3 userId

Unique hash identifier for a user. If not supplied, current user.

=cut

sub canEdit {
        my $self = shift;
        my $userId = shift || $self->session->user->userId;
        my $user = WebGUI::User->new($self->session, $userId);
        if ($userId eq $self->get("ownerUserId")) {
                return 1;
        }
        return $user->isInGroup($self->get("groupIdEdit"));
}


#-------------------------------------------------------------------

=head2 canView ( [userId] )

Verifies group and user permissions to be able to view asset. Returns 1 if user is owner of asset. Returns 1 if within the visibility date range of the asset AND user in the View group of asset. Otherwise, returns the result of the canEdit.

Only the owner and the editors can always see the asset, regardless of time/date restrictions on the asset.

=head3 userId

Unique hash identifier for a user. If not specified, uses current userId.

=cut


sub canView {
        my $self = shift;
        my $eh = $self->session->errorHandler;
        my $userId = shift;
        my $user;
        if (defined $userId) {
                $user = WebGUI::User->new($self->session, $userId);
        }
        else {
                $user =  $self->session->user;
                $userId = $user->userId();
        }
        if ($userId eq $self->get("ownerUserId")) {
                return 1;
        } elsif ($user->isInGroup($self->get("groupIdView"))) {
                return 1;
        }
        return $self->canEdit($userId);
}


#-------------------------------------------------------------------

=head2 checkView ( )

Returns error messages if a user can't view due to publishing problems, otherwise it sets the cookie and returns undef. This is sort of a hack until we find something better.

=cut

sub checkView {
        my $self = shift;
        return $self->session->privilege->noAccess() unless $self->canView;
        my ($var, $http) = $self->session->quick(qw(var http));
        if ($var->isAdminOn && $self->get("state") =~ /^trash/) { # show em trash
                $http->setRedirect($self->getUrl("func=manageTrash"));
                return "redirect";
        } elsif ($var->isAdminOn && $self->get("state") =~ /^clipboard/) { # show em clipboard
                $http->setRedirect($self->getUrl("func=manageClipboard"));
                return "redirect";
        } elsif ($self->get("state") ne "published" && $self->get("state") ne "archived") { # tell em it doesn't exist anymore
                $http->setStatus("410");
                my $notFound = WebGUI::Asset->getNotFound($self->session);
                $self->session->asset($notFound);
                return $notFound->www_view;
        }
        $self->logView();
        return undef;
}

#-------------------------------------------------------------------

=head2 definition ( [ definition ] )

Basic definition of an Asset. Properties, default values. Returns an array reference containing tableName,className,properties

=head3 definition

An array reference containing additional information to include with the default definition.

=cut

sub definition {
    my $class = shift;
    my $session = shift;
    my $definition = shift || [];
        my $i18n = WebGUI::International->new($session, "Asset");
        my %properties;
        tie %properties, 'Tie::IxHash';
        %properties = (
                    title=>{
                                            tab=>"properties",
                                            label=>$i18n->get(99),
                                            hoverHelp=>$i18n->get('99 description'),
                        fieldType=>'text',
                        defaultValue=>'Untitled',
                                            filter=>'fixTitle',
                    },
                    menuTitle=>{
                                            tab=>"properties",
                                            label=>$i18n->get(411),
                                            hoverHelp=>$i18n->get('411 description'),
                                            uiLevel=>1,
                        fieldType=>'text',
                                            filter=>'fixTitle',
                        defaultValue=>undef
                    },
                    url=>{
                                            tab=>"properties",
                                            label=>$i18n->get(104),
                                            hoverHelp=>$i18n->get('104 description'),
                                            uiLevel=>3,
                        fieldType=>'text',
                        defaultValue=>undef,
                                            filter=>'fixUrl'
                    },
                                    isHidden=>{
                                            tab=>"display",
                                            label=>$i18n->get(886),
                                            hoverHelp=>$i18n->get('886 description'),
                                            uiLevel=>6,
                                            fieldType=>'yesNo',
                                            defaultValue=>0
                                        },
                                    newWindow=>{
                                            tab=>"display",
                                            label=>$i18n->get(940),
                                            hoverHelp=>$i18n->get('940 description'),
                                            uiLevel=>9,
                                            fieldType=>'yesNo',
                                            defaultValue=>0
                                        },
                                    encryptPage=>{
                                            fieldType=>'yesNo',
                                            tab=>"security",
                                            label=>$i18n->get('encrypt page'),
                                            hoverHelp=>$i18n->get('encrypt page description'),
                                            uiLevel=>6,
                                            defaultValue=>0
                                        },
                    ownerUserId=>{
                                            tab=>"security",
                                            label=>$i18n->get(108),
                                            hoverHelp=>$i18n->get('108 description'),
                                            uiLevel=>6,
                        fieldType=>'user',
                        defaultValue=>'3'
                    },
                    groupIdView=>{
                                            tab=>"security",
                                            label=>$i18n->get(872),
                                            hoverHelp=>$i18n->get('872 description'),
                                            uiLevel=>6,
                        fieldType=>'group',
                        defaultValue=>'7'
                    },
                    groupIdEdit=>{
                                            tab=>"security",
                                            label=>$i18n->get(871),
                                            excludeGroups=>[1,7],
                                            hoverHelp=>$i18n->get('871 description'),
                                            uiLevel=>6,
                        fieldType=>'group',
                        defaultValue=>'4'
                    },
                    synopsis=>{
                                            tab=>"meta",
                                            label=>$i18n->get(412),
                                            hoverHelp=>$i18n->get('412 description'),
                                            uiLevel=>3,
                        fieldType=>'textarea',
                        defaultValue=>undef
                    },
                    extraHeadTags=>{
                                            tab=>"meta",
                                            label=>$i18n->get("extra head tags"),
                                            hoverHelp=>$i18n->get('extra head tags description'),
                                            uiLevel=>5,
                        fieldType=>'textarea',
                        defaultValue=>undef
                    },
                                    isPackage=>{
                                            label=>$i18n->get("make package"),
                                            tab=>"meta",
                                            hoverHelp=>$i18n->get('make package description'),
                                            uiLevel=>7,
                                            fieldType=>'yesNo',
                                            defaultValue=>0
                                        },
                                    isPrototype=>{
                                            tab=>"meta",
                                            label=>$i18n->get("make prototype"),
                                            hoverHelp=>$i18n->get('make prototype description'),
                                            uiLevel=>9,
                                            fieldType=>'yesNo',
                                            defaultValue=>0
                                        },
                                    status=>{
                                            noFormPost=>1,
                                            fieldType=>'hidden',
                                            defaultValue=>'pending'
                                        },
                                    assetSize=>{
                                            noFormPost=>1,
                                            fieldType=>'hidden',
                                            defaultValue=>0
                                        },
    );
    push(@{$definition}, {
            assetName=>$i18n->get("asset"),
        tableName=>'assetData',
                autoGenerateForms=>1,
        className=>'WebGUI::Asset',
                icon=>'assets.gif',
        properties=>\%properties
        }
    );
    return $definition;
}


#-------------------------------------------------------------------

=head2 DESTROY ( )

Completely remove an asset from existence.

=cut

sub DESTROY {
        my $self = shift;
        # something bad happens when the following is enabled, not sure why
        # must check this out later
        #$self->{_parent}->DESTROY if (exists $self->{_parent});
        $self->{_firstChild}->DESTROY if (exists $self->{_firstChild});
        $self->{_lastChild}->DESTROY if (exists $self->{_lastChild});
        $self = undef;
}


#-------------------------------------------------------------------

=head2 fixUrl ( string )

Returns a URL, removing invalid characters and making it unique.

=head3 string

Any text string. Most likely will have been the Asset's name or title.

=cut

sub fixUrl {
        my $self = shift;
        my $url = shift;

        # build a URL from the parent
        unless ($url) {
                $url = $self->getParent->get("url");
                $url =~ s/(.*)\..*/$1/;
                $url .= '/'.$self->getValue("menuTitle");
        }
        $url = $self->session->url->urlize($url);

        # fix urls used by uploads and extras
        # and those beginning with http
        my @badUrls = ($self->session->config->get("extrasURL"), $self->session->config->get("uploadsURL"));
        foreach my $badUrl (@badUrls) {
                if ($badUrl =~ /^http/) {
                        $badUrl =~ s/^http.*\/(.*)$/$1/;
                } else {
                        $badUrl =~ s/^\/(.*)/$1/;
                }
                if ($url =~ /^$badUrl/) {
                        $url = "_".$url;
                }
        }

        # urls can't be longer than 250 characters
        if (length($url) > 250) {
                $url = substr($url,220);
        }

        # remove multiple extensions from the url if there are some
        while ($url =~ m{^(.*)\.\w+(/.*)$}) {
                $url =~ s{^(.*)\.\w+(/.*)$}{$1$2}ig;
        }

        # add automatic extension if we're supposed to
        if ($self->session->setting->get("urlExtension") ne "" #don't add an extension if one isn't set
                && !($url =~ /\./) #don't add an extension of the url already contains a dot
                && $self->get("url") eq $self->getId # only add it if we're creating a new url
                ) {
                $url .= ".".$self->session->setting->get("urlExtension");
        }

        # check to see if the url already exists or not, and increment it if it does
        if ($self->urlExists($self->session, $url, {assetId=>$self->getId})) {
                my @parts = split(/\./,$url);
                if ($parts[0] =~ /(.*)(\d+$)/) {
                        $parts[0] = $1.($2+1);
                } else {
                        $parts[0] .= "2";
                }
                $url = join(".",@parts);
                $url = $self->fixUrl($url);
        }
        return $url;
}


#-------------------------------------------------------------------

=head2 fixTitle ( string )

Fixes a title by eliminating HTML from it.

=head3 string

Any text string. Most likely will have been the Asset's name or title.

=cut

sub fixTitle {
        my $self = shift;
        return WebGUI::HTML::filter(shift || $self->getValue("title") || 'Untitled', 'all');
}


#-------------------------------------------------------------------

=head2 get ( [propertyName] )

Returns a reference to a list of properties (or specified property) of an Asset.

=head3 propertyName

Any of the values associated with the properties of an Asset. Default choices are "title", "menutTitle", "synopsis", "url", "groupIdEdit", "groupIdView", "ownerUserId",  and "assetSize".

=cut

sub get {
        my $self = shift;
        my $propertyName = shift;
        if (defined $propertyName) {
                return $self->{_properties}{$propertyName};
        }
        my %copyOfHashRef = %{$self->{_properties}};
        return \%copyOfHashRef;
}



#-------------------------------------------------------------------

=head2 getAdminConsole ( )

Returns a reference to a WebGUI::AdminConsole object.

=cut

sub getAdminConsole {
        my $self = shift;
        unless (exists $self->{_adminConsole}) {
                $self->{_adminConsole} = WebGUI::AdminConsole->new($self->session,"assets");
        }
        $self->{_adminConsole}->setIcon($self->getIcon);
        return $self->{_adminConsole};
}

#-------------------------------------------------------------------

=head2 getAssetAdderLinks ( [addToUrl, type] )

Returns an arrayref that contains a label (name of the class of Asset) and url (url link to function to add the class).

=head3 addToUrl

Any text to append to the getAssetAdderLinks URL. Usually name/variable pairs to pass in the url. If addToURL is specified, the character ";" and the text in addToUrl is appended to the returned url.

=head3 type

A string indicating which type of adders to return. Defaults to "assets". Choose from "assets", "assetContainers", or "utilityAssets".

=cut

sub getAssetAdderLinks {
        my $self = shift;
        my $addToUrl = shift;
        my $type = shift || "assets";
        my %links;
        my $classesInType = $self->session->config->get($type);
        if (ref $classesInType ne "ARRAY") {
                $classesInType = [];
        }
        foreach my $class (@{$classesInType}) {
                next unless $class;
                my %properties = (
                        className=>$class,
                        dummy=>1
                );
                my $newAsset = WebGUI::Asset->newByPropertyHashRef($self->session,\%properties);
                next unless $newAsset;
                my $uiLevel = eval{$newAsset->getUiLevel()};
                if ($@) {
                        $self->session->errorHandler->error("Couldn't get UI level of ".$class.". Root cause: ".$@);
                        next;
                }
                next if ($uiLevel > $self->session->user->profileField("uiLevel"));# && !$self->session->user->isInGroup(3));
                my $canAdd = eval{$class->canAdd($self->session)};
                if ($@) {
                        $self->session->errorHandler->error("Couldn't determine if user can add ".$class." because ".$@);
                        next;
                } 
                next unless ($canAdd);
                my $label = eval{$newAsset->getName()};
                if ($@) {
                        $self->session->errorHandler->error("Couldn't get the name of ".$class."because ".$@);
                        next;
                }
                my $url = $self->getUrl("func=add;class=".$class);
                $url = $self->session->url->append($url,$addToUrl) if ($addToUrl);
                $links{$label}{url} = $url;
                $links{$label}{icon} = $newAsset->getIcon;
                $links{$label}{'icon.small'} = $newAsset->getIcon(1);
        }
        my $constraint;
        if ($type eq "assetContainers") {
                $constraint = $self->session->db->quoteAndJoin($self->session->config->get("assetContainers"));
        } elsif ($type eq "utilityAssets") {
                $constraint = $self->session->db->quoteAndJoin($self->session->config->get("utilityAssets"));
        } else {
                $constraint = $self->session->db->quoteAndJoin($self->session->config->get("assets"));
        }
        if ($constraint) {
                my $sth = $self->session->db->read("select asset.className,asset.assetId,assetData.revisionDate from asset left join assetData on asset.assetId=assetData.assetId where assetData.isPrototype=1 and asset.state='published' and asset.className in ($constraint) and assetData.revisionDate=(SELECT max(revisionDate) from assetData where assetData.assetId=asset.assetId) group by assetData.assetId");
                while (my ($class,$id,$date) = $sth->array) {
                        my $asset = WebGUI::Asset->new($self->session,$id,$class,$date);
                        next unless ($asset->canView && $asset->canAdd($self->session) && $asset->getUiLevel <= $self->session->user->profileField("uiLevel"));
                        my $url = $self->getUrl("func=add;class=".$class.";prototype=".$id);
                        $url = $self->session->url->append($url,$addToUrl) if ($addToUrl);
                        $links{$asset->getTitle}{url} = $url;
                        $links{$asset->getTitle}{icon} = $asset->getIcon;
                        $links{$asset->getTitle}{'icon.small'} = $asset->getIcon(1);
                        $links{$asset->getTitle}{'isPrototype'} = 1;
                        $links{$asset->getTitle}{'asset'} = $asset;
                }
                $sth->finish;
        }
        my @sortedLinks;
        foreach my $label (sort keys %links) {
                push(@sortedLinks,{
                        label=>$label,
                        url=>$links{$label}{url},
                        icon=>$links{$label}{icon},
                        'icon.small'=>$links{$label}{'icon.small'},
                        isPrototype=>$links{$label}{isPrototype},
                        asset=>$links{$label}{asset}
                        });     
        }
        return \@sortedLinks;
}


#-------------------------------------------------------------------

=head2 getContainer ( )

Returns a reference to the container asset. If this asset is a container it returns a reference to itself. If this asset is not attached to a container it returns its parent.

=cut

sub getContainer {
        my $self = shift;
        if (WebGUI::Utility::isIn($self->get("className"), @{$self->session->config->get("assetContainers")})) {
                return $self;
        } else {
#               $self->session->asset($self->getParent);
                return $self->getParent;
        }
}

#-------------------------------------------------------------------

=head2 getDefault ( session )

Constructor. Returns the default object, which is also known by some as the "Home Page". The default object is set in the settings.

=head3 session

A reference to the current session.

=cut

sub getDefault {
        my $class = shift;
        my $session = shift;
        return $class->newByDynamicClass($session, $session->setting->get("defaultPage"));
}

#-------------------------------------------------------------------

=head2 getEditTabs ()

Returns a list of arrayrefs, one per extra tab to add to the edit
form.  The default is no extra tabs.  Override this in a subclass to
add extra tabs.

=cut

sub getEditTabs {
        my $self = shift;
        return ();
}

#-------------------------------------------------------------------

=head2 getEditForm ()

Creates and returns a tabform to edit parameters of an Asset.

=cut

sub getEditForm {
        my $self = shift;
        my $i18n = WebGUI::International->new($self->session, "Asset");
        my $ago = $i18n->get("ago");
        my $rs = $self->session->db->read("select revisionDate from assetData where assetId=? order by revisionDate desc limit 5", [$self->getId]);
        my $uiLevelOverride = $self->get("className");
        $uiLevelOverride =~ s/\:\:/_/g;
        my $tabform = WebGUI::TabForm->new($self->session,undef,undef,$self->getUrl(),$uiLevelOverride);
        if ($self->session->config->get("enableSaveAndCommit")) {
                $tabform->submitAppend(WebGUI::Form::submit($self->session, {name=>"saveAndCommit", value=>$i18n->get("save and commit")}));
        }
        $tabform->hidden({
                name=>"func",
                value=>"editSave"
                });
        if ($self->getId eq "new") {
                $tabform->hidden({
                        name=>"assetId",
                        value=>"new"
                        });
                $tabform->hidden({
                        name=>"class",
                        value=>$self->session->form->process("class","className")
                        });
        } else {
                my $ac = $self->getAdminConsole;
                $ac->addSubmenuItem($self->getUrl("func=manageRevisions"),$i18n->get("revisions").":");
                while (my ($version) = $rs->array) {
                        my ($interval, $units) = $self->session->datetime->secondsToInterval(time() - $version);
                        $ac->addSubmenuItem($self->getUrl("func=edit;revision=".$version), $interval." ".$units." ".$ago);
                }
        }
        if ($self->session->form->process("proceed")) {
                $tabform->hidden({
                        name=>"proceed",
                        value=>$self->session->form->process("proceed")
                        });
        }
        # create tabs
        $tabform->addTab("properties",$i18n->get("properties"));
        $tabform->addTab("display",$i18n->get(105),5);
        $tabform->addTab("security",$i18n->get(107),6);
        $tabform->addTab("meta",$i18n->get("Metadata"),3);
        # process errors
        my $errors = $self->session->stow->get('editFormErrors');
        if ($errors) {
                $tabform->getTab("properties")->readOnly(
                        -value=>"<p>Some error(s) occurred:<ul><li>".join('</li><li>', @$errors).'</li></ul></p>',
                )
        }
        $tabform->getTab("properties")->readOnly(
                -label=>$i18n->get("asset id"),
                -value=>$self->get("assetId"),
                -hoverHelp=>$i18n->get('asset id description'),
                );

        foreach my $tabspec ($self->getEditTabs) {
                $tabform->addTab(@$tabspec);
        }

        foreach my $definition (reverse @{$self->definition($self->session)}) {
                my $properties = $definition->{properties};
                next unless ($definition->{autoGenerateForms});

                foreach my $fieldName (keys %{$properties}) {
                        my %fieldHash = %{$properties->{$fieldName}};
                        my %params = (name => $fieldName,
                                      value => $self->getValue($fieldName));
                        next if exists $fieldHash{autoGenerate} and not $fieldHash{autoGenerate};

                        # Kludge.
                        if (isIn($fieldHash{fieldType}, 'selectBox', 'workflow') and ref $params{value} ne 'ARRAY') {
                                $params{value} = [$params{value}];
                        }

                        if (exists $fieldHash{visible} and not $fieldHash{visible}) {
                                $params{fieldType} = 'hidden';
                        } else {
                                %params = (%params, %fieldHash);
                                delete $params{tab};
                        }

                        my $tab = $fieldHash{tab} || "properties";
                        $tabform->getTab($tab)->dynamicField(%params);
                }
        }

        if ($self->session->setting->get("metaDataEnabled")) {
                my $meta = $self->getMetaDataFields();
                foreach my $field (keys %$meta) {
                        my $fieldType = $meta->{$field}{fieldType} || "text";
                        my $options;
                        # Add a "Select..." option on top of a select list to prevent from
                        # saving the value on top of the list when no choice is made.
                        if($fieldType eq "selectList") {
                                $options = {"", $i18n->get("Select")};
                        }
                        $tabform->getTab("meta")->dynamicField(
                                                name=>"metadata_".$meta->{$field}{fieldId},
                                                label=>$meta->{$field}{fieldName},
                                                uiLevel=>5,
                                                value=>$meta->{$field}{value},
        &n